I always enjoy reading what other people are AppleScripting as it usually gives me some ideas about how to better use my Mac. I use LaunchBar as my application launcher, so Brett Terpstra’s script didn’t directly hit the sweet spot of fixing a problem I had, but it did get me thinking about what I do when I want to hide the current application.

I didn’t have any tricks, so shortly after reading the post, I wrote this dead simple AppleScript to hide the frontmost app:

tell application "System Events"
    set current_app to name of first process where frontmost is true
    set visible of process current_app to false
end tell

Just as I was about to assign this to a FastScripts keyboard shortcut, it occurred to me that I was probably over-thinking it and OS X had to already support this functionality in some way, right?

A Google search later confirmed it: Cmd-H hides the current app, and for bonus points, you have Cmd-Option-H which hides all apps except for the current app.

Two great keyboard shortcuts I was previously unaware of. Thanks, Brett. It all started with your post.

∞ Permalink

I wrote this subroutine tonight as I watched Game 5 of the ALCS.  It takes a number and a desired length and then zero pads it.

on zero_pad(value, string_length)
    set string_zeroes to ""
    set digits_to_pad to string_length - (length of (value as string))
    if digits_to_pad > 0 then
        repeat digits_to_pad times
            set string_zeroes to string_zeroes & "0" as string
        end repeat
    end if
    set padded_value to string_zeroes & value as string
    return padded_value
end zero_pad

You could call it like this:

set new_value to zero_pad(7, 3)

…which would return a well-known secret agent’s alias:

007

Or you could call it like this:

set month to zero_pad(month of (current date),2)

…which for September would return a nicely zero-padded month value:

09

This worked exactly as I wanted it to, but if anyone out there has a more efficient way to do it I would love to see it.

Here’s a quick one for the folks who are learning AppleScript out there…

The other day I got temporarily stuck on an AppleScript I’ve been tinkering with because I could not figure out how to test for what I perceived as a “null” value.  I had set a variable to a property of a class and was getting the result “missing value”.

Here’s some example code that illustrates it:

tell application "Finder" to set this_variable to the size of the desktop

The result is:

missing value

At first, I didn’t anything of it.  I told myself, “Easy.  Just figure out how to test for a null value and keep moving.”  Then I stopped to think about it.  As far as I knew there was no isNull() or similar function in AppleScript.  I quickly checked my trusty AppleScript 1-2-3 book and couldn’t find anything about testing for null values.

So my next thought was, “OK.  This is just about you learning how to think in AppleScript.  What is the AppleScript way to do this?”  A couple seconds later, I was convinced I had it.  Using the example above, my next line was equivalent to:

if (this_variable is equal to "") then
    display dialog "it worked"
end if

Nope.  I thought I may have gotten the syntax wrong, so I played around with that for awhile, but it didn’t work.

Of course if you Google something long enough, you will probably find the answer, and I found it, but it did take a little more time than I expected.  The solution was not only right in front of me but is ridiculously simple.

This statement does exactly what I was trying to accomplish.

if (this_variable is missing value) then
    display dialog "it worked"
end if

In AppleScript, “missing value” is an AppleScript constant and you can test for it.  Doh!  My brain got tracked in on “testing for null”, and I didn’t even consider that “missing value” was more than just an error message.  Bingo.  Lesson learned.

I know this is simple stuff, but these are the little stumbling blocks I am plowing through right now.  Hopefully this post will help another AppleScript newbie out there.

I’ve been trying out TaskPaper of late and stumbled across this page on their company wiki.

This is a gem.  What a great resource for power users of the application.

∞ Permalink

tell application "Ken"
   set new_applescript_ideas to every idea that hits me while I use my Mac
   try
       create_applescript(new_applescript_ideas)
   on error
      display dialog "Back to the drawing board..."
   end try
end tell

If you are still reading after that geek-fest above, I have to say I am pretty impressed!   That pseudo-script however really expresses the shift that is going on inside my brain right now.  Learning AppleScript has become a recent hobby of mine, and while I can’t give it eight hours a day, I am trying to get a couple hours here and there each week in order to improve my scripting chops.

What I’ve recognized is that sometime after the intial dozen or so hours of trying to figure out why this language is fairly easy to read but harder to write, you hit a breakthrough and start getting it. Then, after you knock off a simple script or two that actually does what you want, you get your second wind.

For me that second wind got me starting to “think in AppleScript”.  I look at what I’m doing on my Mac now with a much different perspective.  I question pretty much anything that I do that seems remotely time intensive or rote and ask myself, “can you script that?”   I am adding scripts to my “ideas list” faster than I’m able to write them at the moment.

Now it’s all about getting that other part of my brain, the one has to execute and write the scripts, to catch up with the part that is coming up with all of these scripting ideas.

It’s too bad that my newly acquired Applescript thinking super power can’t write a script to do that

Yesterday I read that DropBox announced their new iPhone app, and it occurred to me that you could set up the Dropbox iPhone app to clip images directly into Yojimbo with very minimal effort.  I was so pumped.  This was a total game changer.

Here’s how to do it:

(Note:  I’m assuming that you have Yojimbo installed on your Mac and Dropbox installed on both your iPhone and Mac.  If not, download Dropbox here and Yojimbo here.)

1. On your Mac, create a new folder called “Clip to Yojimbo” in your Dropbox folder:

1.  Copy and past the below code into Script Editor.  This will become a folder action that runs anytime a file is added to the “Clip to Yojimbo” folder (note: you will have to enable folder actions if they are not already set up).  Save the script to your Mac’s Library/Scripts/Folder Actions folder as “import to Yojimbo” or whatever name you like.

on adding folder items to this_folder after receiving these_items
    repeat with x from 1 to the count of these_items
        set theFile to item x of these_items
        try
            tell application "Yojimbo"
                import theFile
            end tell
        end try
    end repeat
end adding folder items to

Note for Scripters:  You can certainly get a little fancier with the Applescript, i.e. move the picture to an archive folder after the import is complete, etc. but this is all you need to get the basic import done.

1.  Assign the “import to Yojimbo” folder action to the “Clip to Yojimbo” folder.

1. That’s it.  Now it is time to test it out.  Go to your iPhone, go to DropBox and navigate to the “Clip to Yojimbo” folder. Take a picture.

1. If you are at your Mac, you will see the picture almost immediately show up in the Dropbox folder.

1.  A couple seconds later, it will import right into Yojimbo.

You’re done.  Pretty cool, right?  You can watch the whole process happen in real time on your Mac if you have the Finder open to the “Clip to Yojimbo” folder alongside an open Yojimbo window.  It is almost instantaneous.  The lack of an iPhone app for Yojimbo was the reason I started using Evernote, so this is pretty exciting.   It probably just swung my decision pendulum back to using Yojimbo.

I have been pushing myself of late to take my Mac knowledge to that next level, and as far as I am concerned the path to get there goes straight through Mac OS X’s automation tools, and Applescript in particular.

My strategy to learning Applescript is pretty simple.   I’ve armed myself with Sal Soghoian’s excellent book, AppleScript 1-2-3, and I periodically assign myself small projects to script real world tasks.  Ironically enough, at least until I get a little more experienced, writing a script is not always the fastest or easiest way to get things done.  However, you’ve got to start somewhere and to paraphrase President Kennedy, we do things not because they are easy but because they are hard.

Several weeks ago I downloaded a trial of Hazel after hearing many good things about it on various podcasts and blogs.  Hazel is an application that makes it easy to establish automated rules for folder management, and I had set up a Hazel rule that automatically moved screenshots from my desktop to a designated screenshots folder (thanks go out to Lifehacker for the idea).  I quickly realized this was a perfect candidate for an Applescript project.  Everything Hazel was doing for me in this rule could be automated with Applescript, and it covered scripting tasks I’d never attempted before.

It sounded simple enough, yet it quickly introduced other choices for me to consider:  How do I tell if a file is really a PNG image versus a text file with a .png extension?  How do I handle a failed move operation?  What do I do if there is an unhandled error?  How do I notify a user of success or failure?  Should I use Growl?  How do I know if Growl is running?  Even though this was a very basic script, I couldn’t help but think of the parallels with what Brent Simmons discusses in his article, Anatomy of a Feature.

Thinking through these questions were important — they created additional opportunities to learn.  By the time I was done I had picked up some good Applescript experience, to include:

• scripting Folder Actions
• how and why to use Uniform Type Identifiers (UTI)
• why you should use System Events in Leopard / Snow Leopard instead of the “for info” command
• how to set up Growl notifications via Applescript
• how to check if an application was running

I’m now keeping a list of similar-sized scripting projects and doing my best to knock them off one by one.  While the going is sometimes slow and the projects are small in scope, each is steadily moving me along the path to become a better scripter.

BTW, here’s the script (It may not seem like much, but trust me — it took me a little time to get there!).

This Applescript is a folder action I wrote that moves screenshots taken with Mac OS X from my Desktop to a designated screenshots folder.  Setting it up requires that you enable folder actions and then assign this script as a folder action to the Desktop folder.

I’m sure variations of this script have been written a million times over, but it was a minor success for me as I practice and learn Applescript.

Here’s the code:

on adding folder items to this_folder after receiving these_items

    -- Check to see if Growl is running
    tell application "System Events" to set growl_running to exists application process "GrowlHelperApp"

    -- Set the location of the new "screenshots folder"
    set screenshot_folder to "Ken's Macbook:Users:kenclark:Pictures:Screenshots:"

    -- Register these notifications with Growl
    if (growl_running) then
        tell application "GrowlHelperApp"
            set the all_notifications_list to {"File Move Complete", "Error"}
            set the enabled_notifications_list to {"File Move Complete", "Error"}
            register as application "Ken's Applescripts" all notifications all_notifications_list default notifications enabled_notifications_list icon of application "Script Editor"
        end tell
    end if

    tell application "Finder"
        repeat with x from 1 to the count of these_items
            set this_item to item x of these_items
            set item_name to name of this_item
            tell application "System Events" to set type_id to type identifier of this_item
            try
                if (type_id is "public.png") and (item_name starts with "Screen shot") then
                    move this_item to screenshot_folder
                    if (growl_running) then
                        tell application "GrowlHelperApp"
                            notify with name "File Move Complete" title "File Move Complete" description item_name & " was successfully moved." application name "Ken's Applescripts"
                        end tell
                    end if
                end if
            on error error_message number error_number
                tell application "GrowlHelperApp"
                    notify with name "Error" title "File move failed" description error_message & "
" & error_number application name "Growl Applescript Test"
                end tell
            end try
        end repeat
    end tell
end adding folder items to

Every now and then I need to copy text into my Twitter client app and need to know if I am bumping against the 140 character limit.  I wrote this quick applescript to simplify my life.  It counts the number of characters in the clipboard and subtracts that number from 140, so you know if your text is too long, too short, or right on target:

display dialog (”Total characters: “ & (count (the clipboard)) & “ “ & “Remaining for Twitter: “ & (140 - (count (the clipboard)))) with title “Character Count”

The best way to use this (outside of using a third-party app that can trigger Applescripts) is to save it to your ~/Library/Scripts folder after you have enabled the Scripts Menu in the OS X menu bar, so you have access to it from any application.